Lingua Libre is in open beta. Be aware that bugs can still occur. Please share your feedback here !

 Actions

Help

SPARQL

From Lingua Libre

Endpoint

Liste des locuteurs

select ?locutor ?locutorLabel
where {
  ?locutor prop:P2 entity:Q3 .
  
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "fr,en" .
  } 
}


Example:

... Loading ...

Enregistrements de Link (Q262) ayant un lien vers un élément Wikidata (P12)

select ?record ?recordLabel ?languageLabel ?wid
where {
  ?record prop:P2 entity:Q2 .
  ?record prop:P5 entity:Q262 .
  ?record prop:P4 ?language .
  ?record prop:P12 ?wid .
  
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "fr,en" .
  } 
}

Tous les enregistrement triés par langue et par niveau de langue

select ?record ?recordLabel ?locutorLabel ?languageLabel ?languageLevelLabel
where {
  ?record prop:P2 entity:Q2 .
  ?record prop:P5 ?locutor .
  ?record prop:P4 ?language .
  
  ?locutor llp:P4 ?languageStatement .
  ?languageStatement llv:P4 ?language .
  ?languageStatement llq:P16 ?languageLevel .
  
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "fr,en" .
  } 
} ORDER BY ?languageLabel ?languageLevelLabel

Tous les enregistrements liés avec un élément wikidata, en récupérant là-bas les coordonnées géographique

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX ll: <https://lingualibre.fr/entity/> 
PREFIX llt: <https://lingualibre.fr/prop/direct/>
PREFIX lltn: <https://lingualibre.fr/prop/direct-normalized/>

select distinct ?record ?transcription ?languageLabel ?wikidataLabel ?coord
where {
  ?record llt:P2 ll:Q2 .
  ?record llt:P4 ?language .
  ?record llt:P7 ?transcription .
  ?record lltn:P12 ?wikidataItem .
  
  SERVICE <https://query.wikidata.org/sparql> {
    OPTIONAL { ?wikidataItem wdt:P625 ?coord . }
    OPTIONAL {
      ?wikidataItem rdfs:label ?wikidataLabel .
      FILTER (LANG(?wikidataLabel) = "fr") .
    }
  }

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "fr,en" .
  } 
}